端口
前面講過，各種存儲器都和CPU的地址線、數據線、控制線相連。CPU在操控它們的時候，把它們都當作內存來對待，把它們總的看做一個由若干存儲單元組成的邏輯存儲器，這個邏輯器我們稱其為內存地址空間。
在PC機系統中，和CPU通過總線相連的芯片除各種存儲器外，還有以下3種芯片：
1）各種接口卡（比如：網卡、顯卡）上的接口芯片，它們控制接口卡進行工作；
2）主板上的接口芯片，CPU通過它們對部分外設進行訪問；
3）其他芯片，用來存儲相關的系統信息，或進行相關的輸入輸出處理。
在這些芯片中，都有一組可以由CPU讀寫的寄存器。這些寄存器，它們在物理上可能處于不同的芯片中，但是它們在以下兩點上相同：
1）都和CPU的總線相連，當然這種連接是通過它們所在的芯片進行的；
2）CPU對它們進行讀或寫的時候都通過控制線向它們所在的芯片發出端口讀寫命令。
可見，從CPU的角度，將這些寄存器都當作端口，對它們進行統一編址，從而建立了一個統一的端口地址空間。每一個端口在地址空間中都有一個地址。
CPU可以直接讀寫3個地方的數據：
1）CPU內部的寄存器；
2）內存單元；
3）端口中。（芯片中的寄存器）
端口的讀寫
在訪問端口的時候，CPU通過端口地址來定位端口。因為端口所在的芯片和CPU通過總路線相連，所以，端口地址和內存地址一樣，通過地址總路線來傳送。在PC系統中，CPU最多可以定位64K個不同的端口。則端口地址的范圍為0~65535。
對端口的讀寫不能用mov，push，pop等內存讀寫指令。
端口的讀寫指令只有兩條：in和out，分別用于從端口讀出數據和往端口寫入數據。
我們來看一下CPU執行內存訪問指令和端口訪問指令時候，總線上的信息：
1）訪問內存：
mov ax,ds:[8] ;假設執行前(ds)=0
執行時與總路線相關的操作：
（1）CPU通過地址線將地址信息8發出；
（2）CPU通過控制線發出內存讀命令，選中存儲器芯片，并通知它，將要從中讀取數據；
（3）存儲器將8號單元中的數據通過數據線送入CPU。
2）訪問端口：
in al,60h ;從60h號端口讀入一個字節
執行時與總路線相關的操作：
（1）CPU通過地址線將地址信息60h發出；
（2）CPU通過控制線發出端口讀命令，選中端口所在的芯片，并通知它，將要從中讀取數據；
（3）端口所在的芯片將60h端口中的數據通過數據線送入CPU。
在in和out指令中，只能使用ax或al來存放從端口中讀入的數據或要發送到端口中的數據。訪問8位端口時用al，訪問16位端口時用ax。
對0~255以內的端口進行讀寫時：
in al,20h ;從20h端口讀入一個字節
out 20h,al ;往20h端口寫入一個字節
對256~65535的端口進行讀寫時，端口號放在dx中：
mov dx,3f8h ;將端口號3f8h送入dx
in al,dx ;從3f8h端口讀入一個字節
out dx,al ;向3f8h端口寫入一個字節
CMOS RAM芯片
我們通過對CMOS RAM的讀寫來體會一下對端口的訪問。
PC機中，有一個CMOS RAM芯片，一般簡稱為CMOS。此芯片的特征如下：
1）包含一個實時鐘和一個有128個存儲單元的RAM存儲器（早期的計算機為64個字節）。
2）該芯片靠電池供電。所以，關機后其內部的實時鐘仍可正常工作，RAM中的信息不丟失。
3）128個字節的RAM中，內部實時鐘占用0~0dh單元來保存時間信息，其余大部分單元用來保存系統配置信息，供系統啟動時BIOS程序讀取。BIOS也提供了相關的程序，使我們可以在開機的時候配置CMOS RAM中的系統信息。
4）該芯片內部有兩個端口，端口地址為70h和71h。CPU通過這兩個端口來讀寫CMOS RAM。
5）70h為地址端口，存放要訪問的CMOS RAM單元的地址：71h為數據端口，存放從選定的CMOS RAM單元中讀取的數據?？梢?，CPU對CMOS RAM的讀寫分兩步進行了，比如：讀CMOS RAM的2號單元：
（1）將2送入端口70h；
（2）從71h讀出2號單元的內容。
檢測點14.1
1）編程：讀取CMOS RAM的2號單元的內容。
mov al,2h
out 70h,al ;把2寫入地址端口。
in 71h,al ;把數據端口的內容讀出放入al寄存器。
2）編程：向CMOS RAM的2號單元寫入0。
mov al,2h
out 70h,al ;把2寫入地址端口
mov al,0
out 71h,al ;把0寫入數據端口
shl和shr指令
shl和shr是邏輯移位指令。
shl是邏輯左移指令，它的功能為：
1）將一個寄存器或內存單元中的數據向左移位；
2）將最后移出的一位寫入CF中；
3）最低位用0補充。
指令：
mov al,01001000b
shl al,1 ;將al中的數據左移一位
執行后(al)=10010000b，CF=0。
如果移動位數大于1時，必須將移動位數放在cl中。
比如，指令：
mov al,01010001b
mov cl,3
shl al,cl
執行后(al)=10001000b，因為最后移出的一位是1，所以CF=1。
可以看出，將X邏輯左移一位，相當于執行X=X*2。
shr是邏輯右移指令，它和shl所進行的操作剛好相反：
1）將一個寄存器或內存單元中的數據向右移位；
2）將最后移出的一位寫入CF中。
3）最高位用0補充。
指令：
mov al,10000001b
shr al,1 ;將al中的數據右移一位
執行后(al)=01000000b，CF=1
如果移動位數大于1時，必須將移動位數放在cl中。
比如，指令：
mov al,01010001b
mov cl,3
shr al,cl
執行后(al)=00001010b，因為最后移出的一位是0，所以CF=0。
可以看出將X邏輯右移一位，相當于執行X=X/2。
檢測點14.2
編程：用加法和移位指令計算(ax)=(ax)*10
提示：(ax)*10 = (ax)*2 + (ax)*8
assume cs:code
code segment
start: mov ax,1000h
mov bx,ax
shl bx,1 ;(ax)=(ax)*2
mov cl,3
shl ax,cl ;(ax)=(ax)*8
add ax,bx ;(ax)=(ax)*10
code ends
end start
CMOS RAM中存儲的時間信息
在CMOS RAM中，存放著當前的時間：年、月、日、時、分、秒。這6個信息的長度都為1個字節，存放單元為：
秒：0 分：2 時：4 日：7 月：8 年：9
這些數據以BCD碼的方式存放。
BCD碼是以4位二進制數表示十進制數碼的編碼方法，如下表示：
|
十進制
|
0
|
1
|
2
|
3
|
4
|
5
|
6
|
7
|
8
|
9
|
|
BCD碼
|
0000
|
0001
|
0010
|
0011
|
0100
|
0101
|
0110
|
0111
|
1000
|
1001
|
比如：數值26，用BCD碼表示為：0010 0110 （2 6）
可見，一個字節可表示兩個BCD碼。則CMOS RAM存儲時間信息的單元中，存儲了用兩個BCD碼表示的兩位十進制數，高4位的BCD碼表示十位，低4位的BCD碼表示個位。比如：00010100b表示14。
編程：在屏幕中間顯示當前的月份。
分析：這個程序主要做兩部分工作：
（1）從CMOS RAM的8號單元讀出當前月份的BCD碼：
mov al,8 ;首先要向地址端口70h
out 70h,al ;寫入要訪問的單元的地址。
in al,71h ;然后，從數據端口71h中取得指定單元中的數據。
（2）將用BCD碼表示的月份以十進制的形式顯示到屏幕上。
BCD碼值=十進制數碼值，則BCD碼值+30h=十進制數對應的ASCII碼。
從CMOS RAM的8號單元讀出的一個字節中，包含了兩個BCD碼表示的兩位十進制數，高4位的BCD碼表示十位，低4位的BCD碼表示個位。比如：00010100表示14。
我們需要進行兩步工作：
1）將從CMOS RAM的8號單元中讀出的一個字節，分為兩個表示BCD碼值的數據。
mov ah,al ;al中為從CMOS RAM的8號單元讀出的數據
mov cl,4
shr ah,cl ;ah中為月份的十位數碼值
and al,00001111b ;al中為月份的個位數碼值
2）顯示(ah)+30h和(al)+30h對應的ASCII碼字符。
完整程序如下：
assume cs:code
code segment
start:
mov al,8
out 70h,al
in al,71h ;從CMOS RAM的8號單元讀出當前月份的BCD碼。
mov ah,al ;ah,al都存儲著當前月份的BCD碼。
mov cl,4
shr ah,cl ;ah中內容邏輯右移4位，則只剩下月份的十位數碼。
and al,00001111b ;al中內容將只剩下月份的個位數碼。
add ah,30h
add al,30h ;得到十進制數碼的ASCII碼值。
mov bx,0b800h
mov es,bx
mov byte ptr es:[160*12+40*2],ah ;顯示月份的十位數碼
mov byte ptr es:[160*12+40*2+2],al ;顯示月份的個位數碼
mov ax,4c00h
int 21h
code ends
end start