int指令
中斷信息可以來自CPU的內(nèi)部和外部，當(dāng)CPU的內(nèi)部有需要處理的事情發(fā)生的時候，將產(chǎn)生需要馬上處理的中斷信息，引發(fā)中斷過程。
上一章講解了0號中斷和單步中斷，這一章將講解另一種重要的內(nèi)中斷，由int指令引發(fā)的中斷。
int指令
格式：int n
n為中斷類型碼，它的功能是引發(fā)中斷過程。
CPU執(zhí)行int n指令，相當(dāng)于引發(fā)一個n號中斷的中斷過程，執(zhí)行過程如下：
1）取中斷類型碼n；
2）標(biāo)志寄存器入棧，IF=0，TF=0；
3）CS、IP入棧
4）（IP）=（n*4），(CS)=(n*4+2)
從此處轉(zhuǎn)去執(zhí)行n號中斷的中斷處理程序。
可以在程序中使用int指令調(diào)用任何一個中斷的中斷處理程序。
assume cs:code
code segment
start: mov ax,0b800h
move s,ax
mov byte ptr es:[12*160 +40*2],’!’
int 0
code ends
end start
這個程序在Windows2000中的DOS方式下執(zhí)行時，將在屏幕中間顯示一個“！”，然后顯示“Divide overflow”后返回到系統(tǒng)中。“！”是我們編程顯示的，而“Divide overflow”是哪里來的呢？我們的程序中又沒有做除法，不可能產(chǎn)生除法溢出。
程序是沒有做除法，但是在結(jié)尾使用了int 0指令。
CPU執(zhí)行int 0指令時，將引發(fā)中斷過程，執(zhí)行0號中斷處理程序，而系統(tǒng)設(shè)置的0號中斷處理程序的功能是顯示“Divide overflow”，然后返回系統(tǒng)。
int指令的最終功能和call指令相似，都是調(diào)用一段程序。
一般情況下，系統(tǒng)將一些具有一定功能的子程序，以中斷處理程序的方式提供給應(yīng)用程序調(diào)用。我們在編程的時候，可以用int指令調(diào)用這些子程序。當(dāng)然，也可以自己編寫一些中斷處理程序供別人使用。
中斷處理程序可簡稱為中斷例程。
編寫供應(yīng)用程序調(diào)用的中斷例程
前面已經(jīng)編寫過中斷0的中斷例程了，現(xiàn)在我們討論可以供應(yīng)用程序調(diào)用的中斷例程的編寫方法。
1，示例一
編寫、安裝中斷7ch的中斷全程，功能：求一word型數(shù)據(jù)的平方。
參數(shù)：(ax)=要計算的數(shù)據(jù)。
返回值：dx、ax中存放結(jié)果的高16位和低16位。
應(yīng)用舉例：求2*3456^2
assume cs:code
code segment
start: mov ax,3456 ;(ax)=3456
int 7ch ;調(diào)用中斷7ch的中斷例程，計算ax中的數(shù)據(jù)的平方
add ax,ax
adc dx,dx ;dx:ax存放結(jié)果，將結(jié)果乘以2
mov ax,4c00h
int 21h
code ends
end start
分析，我們要做三部分工作：
1）編寫實現(xiàn)求平方功能的程序；
2）安裝程序，我們將其安裝在0:200處；
3）設(shè)置中斷向量表，將程序的入口地址保存在7ch表項中，使其成為中斷7ch的中斷例程。
安裝程序如下：
assume cs:code
code segment
start: mov ax,cs
mov ds,ax
mov si, offset sqr ;設(shè)置ds:si指向源地址
mov ax,0
mov es,ax
mov di, 200h ;設(shè)置es:di指向目的地址
mov cx, offset sqrend – offset sqr ;設(shè)置cx為傳輸長度
cld ;設(shè)置傳輸方向為正
rep movsb
mov ax,0
mov es,ax
mov word ptr es:[7ch*4],200h ;設(shè)置中斷向量表 偏移地址
mov word ptr es:[7ch*4+2],0 ;設(shè)置中斷向量表，段地址
mov ax,4c00h
int 21h
sqr: mul ax
iret
sqrend: nop
code ends
end start
注意，在中斷例程sqr的最后，要使用iret指令。用匯編語法描述，iret指令的功能為：
pop IP
pop CS
popf
CPU執(zhí)行int 7ch指令進入中斷例程之前，標(biāo)志寄存器、當(dāng)前的CS和IP被壓入棧中，在執(zhí)行完中斷例程后，應(yīng)該用iret指令恢復(fù)int 7ch執(zhí)行前的標(biāo)志寄存器和CS、IP的值，從而接著執(zhí)行應(yīng)用程序。
int指令和iret指令的配合使用與call指令和ret指令的配合使用具有相似的思路。
2，示例二
編寫、安裝中斷7ch的中斷例程，功能：將一個全是字母，以0結(jié)尾的字符串，轉(zhuǎn)化為大寫。
參數(shù)：ds:si指向字符串的首地址。
應(yīng)用舉例：將data段中的字符串轉(zhuǎn)化為大寫。
assume cs:code
data segment
db ‘conversation’,0
data ends
code segment
start: mov ax,data
mov ds,ax
mov si,0
int 7ch
mov ax,4c00h
int 21h
code ends
end start
安裝程序如下：
assume cs:code
code segment
start: mov ax,cs
mov ds,ax
mov si,offset capital
mov ax,0
mov es,ax
mov di,200h
mov cx,offset capitalend – offset capital
cld
rep movsb
mov ax,0
mov es,ax
mov word ptr es:[7ch*4],200h
mov word ptr es:[7ch*4+2],0
mov ax,4c00h
int 21h
capital: push cx
push si
change: mov cl,[si]
mov ch,0
jcxz ok
and byte ptr [si],11011111b
inc si
jmp short change
ok: pop si
pop cx
iret
capitalend: nop
code ends
end start
在中斷例程capital中用到了寄存器si和cx，編寫中斷例程和編寫子程序的時候具有同樣的問題，就是要避免寄存器的沖突。應(yīng)該注意例程中用到的寄存器的值的保存和恢復(fù)。
對int、iret和棧的深入理解
問題：用7ch中斷例程完成loop指令的功能。
loop s的執(zhí)行需要兩個信息，循環(huán)次數(shù)和到s的位移，所以7ch中斷例程要完成loop指令的功能，也需要這兩個信息作為參數(shù)。我們用cx存放循環(huán)次數(shù)，用bx存放位移。
BIOS和DOS所提供的中斷例程
在系統(tǒng)板的ROM中存放著一套程序，稱為BIOS（基本輸入輸出系統(tǒng)），BIOS中主要包含以下幾部分內(nèi)容：
1）硬件系統(tǒng)的檢測和初始化程序；
2）外部中斷和內(nèi)部中斷的中斷例程；
3）用于對硬件設(shè)備進行了I/O操作的中斷例程；
4）其他和硬件系統(tǒng)相關(guān)的中斷例程。
操作系統(tǒng)DOS也提供了中斷例程，從操作系統(tǒng)的角度來看，DOS的中斷例程就是操作系統(tǒng)向程序員提供的編程資源。
BIOS和DOS在所提供的中斷例程中包含了許多子程序，這些子程序?qū)崿F(xiàn)了程序員在編程的時候經(jīng)常需要用到的功能。程序員在編程的時候，可以用int指令直接調(diào)用BIOS和DOS提供的中斷例程，來完成某些工作。
和硬件設(shè)備相關(guān)的DOS中斷例程中，一般都調(diào)用 了BIOS中的中斷例程。
BIOS和DOS中斷例程的安裝過程
前面我們都是自己編寫中斷例程，將它們放到安裝程序中，然后運行安裝程序，將它們安裝到指定的內(nèi)存區(qū)中。此后，別的應(yīng)用程序才可以調(diào)用。
而BISO和DOS提供的中斷例程是如何安裝到內(nèi)存中的呢？
1）開機后，CPU一加電，初始化(CS)=0FFFFH，(IP)=0，自動從FFFF:0單元開始執(zhí)行程序。FFFF:0處有一條轉(zhuǎn)跳指令，CPU執(zhí)行該指令后，轉(zhuǎn)去執(zhí)行BIOS中的硬件系統(tǒng)檢測和初始化程序。
2）初始化程序?qū)⒔?/span>BIOS所支持的中斷向量，即將BIOS提供的中斷例程的入口地址登記在中斷向量表中。注意，對于BIOS所提供的中斷例程，只需要將入口地址登記在中斷向量表中即可，因為它們是固化到ROM中的程序，一直在內(nèi)存中存在。
3）硬件系統(tǒng)檢測和初始化完成后，調(diào)用int 19h進行操作系統(tǒng)的引導(dǎo)。從此將計算機交由操作系統(tǒng)控制。
4）DOS啟動后，除完成其他工作外，還將它所提供的中斷例程裝入內(nèi)存，并建立相應(yīng)的中斷向量。
檢測點13.2
1）我們可以編程改變FFFF:0處的指令，使得CPU不去執(zhí)行BIOS中的硬件系統(tǒng)檢測和初始化程序。錯，此處內(nèi)存單元為只讀，無法改寫。
2）int 19h中斷例程，可以由DOS提供。錯，int 19h指令是用于引導(dǎo)操作系統(tǒng)的比如DOS，DOS沒有機會改變它。
BIOS中斷例程應(yīng)用
int 10h中斷例程是BIOS提供的中斷例程，其中包含了多個和屏幕輸出相關(guān)的子程序。
一般來說，一個供程序員調(diào)用的中斷例程中往往包括多個子程序，中斷例程內(nèi)部用傳遞進來的參數(shù)來決定執(zhí)行哪一個子程序。BIOS和DOS提供的中斷例程，都用ah來傳遞內(nèi)部子程序的編號。
我們看一下int 10h中斷例程的設(shè)置光標(biāo)位置功能。
mov ah,2 ;置光標(biāo)
mov bh,0 ;第0頁
mov dh,5 ;行號
mov dl,12 ;列號
int 10h
(ah)=2表示調(diào)用第10h號中斷例程的2號子程序，功能為設(shè)置光標(biāo)位置，可以提供光標(biāo)所在的行號(80*25字符模式中：0~24)、列號（80*25字符模式下：0~79），和頁號作為參數(shù)。
(bh)=0，(dh)=5，(dl)=12，設(shè)置光標(biāo)到第0頁，第5頁，第12列。
bh中頁號的含義：內(nèi)存地址空間中，B8000h~BFFFFh共32K的空間，為80*25彩色字符模式的顯示緩沖區(qū)。一屏的內(nèi)容在顯示緩沖區(qū)中共占4000字節(jié)。
顯示緩沖區(qū)分為8頁，每頁4K（≈4000），顯示器可以顯示任意一頁的內(nèi)容。一般情況下，顯示第0頁的內(nèi)容。也就是說，通常情況下，B8000~B8F9F中的4000個字節(jié)的內(nèi)容將出現(xiàn)在顯示器上。(2*80*25=4000個字節(jié))
再看一下int 10h中斷例程的在光標(biāo)位置顯示字符功能。
mov ah,9 ;置光標(biāo)
mov al,’a’ ;字符
mov bl,7 ;顏色屬性
mov bh,0 ;第0頁
mov cx,3 ;字符重復(fù)個數(shù)
int 10h
(ah)=9表示調(diào)用第10h號中斷例程的9號子程序，功能為在光標(biāo)位置顯示字符，可以提供要顯示的字符、顏色屬性、頁號、字符重復(fù)個數(shù)作為參數(shù)。
bh中的顏色屬性的格式如下：
|
|
7
|
6
|
5
|
4
|
3
|
2
|
1
|
0
|
|
含義
|
BL
|
R
|
G
|
B
|
I
|
R
|
G
|
B
|
|
|
閃爍
|
紅色
|
綠色
|
藍色
|
高亮
|
紅色
|
綠色
|
藍色
|
|
|
|
背景
|
|
前景
|
|
例子
|
1
|
1
|
|
|
1
|
|
1
|
|
與顯存中的屬性字節(jié)的格式相同。
編程：在屏幕的5行12列顯示3個紅底高亮閃爍綠色的’a’。
assume cs:code
code segment
start: mov ah,2 ;置光標(biāo)
mov bh,0 ;第0頁
mov dh,5 ;行號
mov dl,12 ;列號
int 10h
mov ah,9 ;置光標(biāo)
mov al,'a' ;字符
mov bl,11001010b ;顏色屬性，閃爍的效果必須在全屏DOS方式下才能看到。
mov bh,0 ;第0頁
mov cx,3 ;字符重復(fù)個數(shù)
int 10h
mov ax,4c00h
int 21h
code ends
end start
DOS中斷例程應(yīng)用
int 21h中斷例程是DOS提供的中斷例程，其中包含了DOS提供給程序員在編程時調(diào)用的子程序。
我們從前一直使用的是int 21h中斷例程的4ch號功能。即程序返回功能，如下：
mov ah,4ch ;程序返回
mov al,0 ;返回值
int 21h
(ah)=4ch表示調(diào)用第21h號中斷例程的4ch號子程序，功能為程序返回，可以提供返回值作為參數(shù)。
我們前面使用這個功能的時候經(jīng)常寫作：
mov ax,4c00h
int 21h
我們看一下int 21h中斷例程的在光標(biāo)位置顯示字符串功能：
ds:dx 指向字符串 ;要顯示的字符串需用“$”作為結(jié)束符
mov ah,9 ;功能號9，表示在光標(biāo)位置顯示字符串
int 21h
(ah)=9表示調(diào)用第21h號中斷例程的9號子程序，功能為在光標(biāo)位置顯示字符串，可以提供要顯示字符串的地址作為參數(shù)。
編程：在屏幕的5行12列顯示字符串“Welcome to masm!”。
;在屏幕的5行12列顯示字符串“Welcome to masm!”
assume cs:code
data segment
db 'Welcome to masm!','$' ;'$'本身不顯示，只起到邊界的作用。
data ends
code segment
start:mov ah,2 ;置光標(biāo)
mov bh,0 ;第0頁
mov dh,5 ;行號
mov dl,12 ;列號
int 10h
mov ax,data
mov ds,ax
mov dx,0 ;ds:dx指向字符串地首地址data:0
mov ah,9
int 21h
mov ax,4c00h
int 21h
code ends
end start
上述程序在屏幕的5行12列顯示字符串“Welcome to masm”，直到遇見“$”（“$”本身并不顯示，只起到邊界的作用）。
如果字符串比較長，遇到行尾，程序會自動轉(zhuǎn)到下一行開頭處繼續(xù)顯示；如果到了最后一行，還能自動上卷一行。
DOS為程序員提供了許多可以調(diào)用的子程序，都包含在int 21h中斷例程中，我們這里只對原理進行了講解，對于DOS提供的所有可調(diào)用子程序的情況，讀者可以參考相關(guān)的書籍。