Win32匯編--使用資源—版本信息資源
有時應用程序需要確保自己運行時使用某一特定版本的DLL，以便確保可以使用某些函數。檢測版本是通過API函數查詢定義于資源中的版本信息來完成的，如果資源中沒有定義版本，那么就無法知道一個文件的版本究竟是多少。
版本信息是以VERSIONINFO類型的資源保存在應用程序中的，里面可以定義的信息包括文件的版本號、創建單位和語種等。版本信息的定義是可選的，一個程序可以不定義版本信息資源，如果定義了的話，也不一定要定義全部信息項目。
如果一個文件定義有版本信息資源，那么在文件的屬性頁（在文件圖標上按鼠標右鍵，在彈出的菜單上選擇）上就會有一個“版本”頁面。
1、版本信息資源的定義
//Version.rc
1 VERSIONINFO
FILEVERSION 1,2,3,4
PRODUCTVERSION 2,3,4,5
FILEOS VOS_WINDOWS32
FILETYPE VFT_APP
FILESUBTYPE VFT2_UNKNOWN
BEGIN
BLOCK "VerFileInfo"
BEGIN
VALUE "Translation", 0x804, 0x4b0
END
BLOCK "StringFileInfo"
BEGIN
BLOCK "080404b0"
BEGIN
VALUE "Comments", "Here is Comments\0"
VALUE "CompanyName", "Here is CompanyName\0"
VALUE "FileDescription", "Here is FileDescription\0"
VALUE "FileVersion", "1,0,0,1\0"
VALUE "InternalName", "Here is InternalName\0"
VALUE "LegalCopyright", "Here is LegalCopyright\0"
VALUE "LegalTrademarks", "Here is LegalTrademarks\0"
VALUE "OriginalFilename", "Here is OriginalFilename\0"
VALUE "PrivateBuild", "Here is PrivateBuild\0"
VALUE "ProductName", "Here is ProductName\0"
VALUE "ProductVersion", "1,0,0,1\0"
VALUE "SpecialBuild", "Here is SpecialBuild\0"
END
END
END
這些定義語句的含義。首先，版本信息定義的語句格式是：
版本信息資源ID VERSIONINFO
固定屬性
BEGIN
塊聲明定義
……
END
版本信息資源ID的取值必須為1，如果不為1則屬性頁上的“版本”信息是無法顯示出來的。（怪異！）
可以定義的固定屬性有：
l FILEVERSION——定義文件版本號，可以定義4個16位版本號xx.xx.xx.xx。
l PRODUCTVERSION——定義產品版本號，可以定義4個16位版本號xx.xx.xx.xx。
l FILELAGSMASK——指定FILELAGS屬性中哪些位有效。
l FILELAGS——文件標志，是一些標志位的組合：VS_FF_PATCHED,VS_FF_DEBUG,VS_FF_PRIVATEBUILD,VS_FF_INFOINFERRED,VS_FF_PRERELEASE和VS_FF_SPECI_ALBUILD。
l FILEOS——定義適用的操作系統，可以定義為VOS_UNKNOWN,VOS_DOS,VOS_NT,VOS_WINDOWS16,VOS_WINDOWS32,VOS_DOS_WINDOWS16,VOS_DOW_WINDOWS32或VOS_NT_WINDOW32。
l FILETYPE——定義文件的子類型。當文件類型是VFT_DRV（驅動程序）的時候，這里可以是VFT2_UNKNOWN,VFT2_DRV_COMM,VFT2_DRV_PRINTER,VFT2_DRV_KEYBOARD,VFT2_DRV_LANGUAGE,VFT2_DRV_DISPLAY,VFT2_DRV_MOUSE,VFT2_DRV_NETWORK,VFT2_DRV_SYSTEM,VFT2_DRV_INSTALLABLE或VFT2_DRV_SOUND;當文件類型是VFT_FONT（字體）的時候，這里可以是VFT2_UNKNOWN,VFT2_FONT_RASTER,VFT2_FONT_VECTOR或VFT2_FONT_TRUETYPE。
當固定屬性定義完成以后，需要定義一些塊聲明，塊聲明有兩種：變量型的信息塊和字符串類型的信息塊，變量類型的信息塊定義如下：
BLOCK “VerFileInfo”
BEGIN
VALUE “Translation”, 語言ID, 字符集ID
……
END
語言ID的常用值有0x0404（繁體中文）、0x0409（美國英語）和0x0804（簡體中文），字符集ID的常用值有0（7位ASCII）、950（臺灣GB5）和1200（Unicode）。一般使用0x804,0x4b0來定義，也就是簡體中文和Unicode（0x4b0=1200）。其他還有很多取值，可以查看Rc.exe的幫助文件。
變量類型信息塊用來表示VERSIONINFO資源中定義有哪些語言和字符集的字符串類型信息塊。如上例中有一句VALUE “Translation”, 0x804, 0x4b0表示對應有一個名為“080404b0”的字符串類型的信息塊。
字符串信息塊的定義語句為：
BLOCK “StringFileInfo”
BEGIN
BLOCK “語言集”
BEGIN
VALUE “字符串名稱”, “字符串”
……
END
END
語言集就是變量類型中定義的，其名稱一定要是將語言ID和字符集ID組合成一個8位的16進制的格式，以上例文件來說明，當變量類型的信息塊中定義0x804, 0x4b0時，語言集名稱就是“080404b0”，在語言集塊的定義中，還可以定義多條字符串型的版本信息，這些版本信息的字符串名有12種，如下表所示：
版本信息字符串類型
|
字符串名稱
|
屬性頁位置
|
說明
|
|
Comments
|
備注
|
有關程序的附加說明信息
|
|
CompanyName
|
公司
|
開發產品的公司
|
|
FileDescription
|
描述
|
有關文件的簡單描述
|
|
FileVersion
|
文件版本
|
如1.50、5.0.RC2等字符串型的版本信息
|
|
InternalName
|
內部名稱
|
|
|
LegalCopyright
|
版權
|
文件的所有版權信息
|
|
LegalTrademarks
|
合法商標
|
文件的所有注冊商標信息
|
|
OriginalFilename
|
源文件名
|
原始文件名，從這里可以得知文件是否被改名
|
|
PrivateBuild
|
個人用內部版本說明
|
作者私人信息
|
|
ProductName
|
產品名稱
|
文件所屬的產品名稱
|
|
ProductVersion
|
產品版本
|
文件所屬的產品的版本號
|
|
SpecialBuild
|
特殊內部版本說明
|
特殊說明
|
定義版本信息字符串的時候要注意，所有的字符串必須是以NULL結尾的串，所以要在字符串尾加上\0。
Demo：給exe添加版本信息
//VersionInfo.rc
//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
#include <resource.h>
#include <Version.h>
//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
#define ICO_MAIN 0x1000 //圖標
ICO_MAIN ICON "Main.ico"
//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
1 VERSIONINFO
FILEVERSION 1,2,3,4
PRODUCTVERSION 2,3,4,5
FILEOS VOS_WINDOWS32
FILETYPE VFT_APP
FILESUBTYPE VFT2_UNKNOWN
BEGIN
BLOCK "VarFileInfo"
BEGIN
VALUE "Translation", 0x804, 0x4b0
END
BLOCK "StringFileInfo"
BEGIN
BLOCK "080404b0"
BEGIN
VALUE "Comments", "Here is Comments\0"
VALUE "CompanyName", "Here is CompanyName\0"
VALUE "FileDescription", "Here is FileDescription\0"
VALUE "FileVersion", "1,0,0,1\0"
VALUE "InternalName", "Here is InternalName\0"
VALUE "LegalCopyright", "Here is LegalCopyright\0"
VALUE "LegalTrademarks", "Here is LegalTrademarks\0"
VALUE "OriginalFilename", "Here is OriginalFilename\0"
VALUE "PrivateBuild", "Here is PrivateBuild\0"
VALUE "ProductName", "Here is ProductName\0"
VALUE "ProductVersion", "1,0,0,1\0"
VALUE "SpecialBuild", "Here is SpecialBuild\0"
END
END
END
//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
//Version.h
/******************************************
* VersionInfo Resource include file
* by LuoYunBin
******************************************/
#define VS_VERSION_INFO 1
#define VS_USER_DEFINED 100
#define VS_FFI_SIGNATURE 0x0FEEF04BD
#define VS_FFI_STRUCVERSION 0x10000
#define VS_FFI_FILEFLAGSMASK 0x3F
#define VS_FF_DEBUG 1
#define VS_FF_PRERELEASE 2
#define VS_FF_PATCHED 4
#define VS_FF_PRIVATEBUILD 8
#define VS_FF_INFOINFERRED 0x10
#define VS_FF_SPECIALBUILD 0x20
#define VOS_UNKNOWN 0
#define VOS_DOS 0x10000
#define VOS_OS216 0x20000
#define VOS_OS232 0x30000
#define VOS_NT 0x40000
#define VOS_BASE 0
#define VOS_WINDOWS16 1
#define VOS_PM16 2
#define VOS_PM32 3
#define VOS_WINDOWS32 4
#define VOS_DOS_WINDOWS16 0x10001
#define VOS_DOS_WINDOWS32 0x10004
#define VOS_OS216_PM16 0x20002
#define VOS_OS232_PM32 0x30003
#define VOS_NT_WINDOWS32 0x40004
#define VFT_UNKNOWN 0
#define VFT_APP 1
#define VFT_DLL 2
#define VFT_DRV 3
#define VFT_FONT 4
#define VFT_VXD 5
#define VFT_STATIC_LIB 7
#define VFT2_UNKNOWN 0
#define VFT2_DRV_PRINTER 1
#define VFT2_DRV_KEYBOARD 2
#define VFT2_DRV_LANGUAGE 3
#define VFT2_DRV_DISPLAY 4
#define VFT2_DRV_MOUSE 5
#define VFT2_DRV_NETWORK 6
#define VFT2_DRV_SYSTEM 7
#define VFT2_DRV_INSTALLABLE 8
#define VFT2_DRV_SOUND 9
#define VFT2_DRV_COMM 0x0A
#define VFT2_DRV_INPUTMETHOD 0x0B
#define VFT2_FONT_RASTER 1
#define VFT2_FONT_VECTOR 2
#define VFT2_FONT_TRUETYPE 3
//VersionInfo.asm
.386
.model flat, stdcall
option casemap :none
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Include 文件定義
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include windows.inc
include user32.inc
includelib user32.lib
include kernel32.inc
includelib kernel32.lib
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 數據段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.const
szTitle db '提示...',0
szMessage db '請用鼠標右鍵單擊本文件，再看看“屬性”菜單項中的“版本”頁！',0
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 代碼段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.code
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
start:
invoke MessageBox,NULL,addr szMessage,addr szTitle,MB_OK or MB_ICONEXCLAMATION
invoke ExitProcess,NULL
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
end start
2、在程序中檢測版本信息
Win32 API中有3個版本信息函數：GetFileVersionSize，GetFileVersionInfo和VerQueryValue，它們駐留在VERSION.DLL文件中，如果在源程序中使用它們，注意要加上include Version.inc以及includelib Version.lib語句。
用這3個函數獲取版本信息的方法是：
首先調用GetFileVersionInfoSize函數檢測文件中有沒有版本信息資源：
invoke GetFileVersionInfoSize, addr szFile, NULL
其中szFile是要檢測的PE文件名字符串，該函數的返回值是版本信息資源的長度，如果返回0，則表示文件不是PE文件或沒有定義版本信息資源。
如果檢測到文件中有版本信息資源，那么可以將版本信息資源讀取到一緩沖區中，緩沖區的長度必須足夠容納上一步返回的資源長度，方法是：
invoke GetFileVersionInfo, addr szFile, NULL, sizeof dbVerInfo, addr dbVerInfo
其中dbVerInfo為一個足夠大的緩沖區。該函數會把整個版本信息資源拷貝到這個緩沖區中。
拷貝到緩沖區中的信息有它自己的格式，必須用VerQueryValue去“解碼”，解碼固定屬性的方法是：
invoke VerQueryValue, addr dbVerInfo, addr szRoot, addr lpBuffer, addr dwLen
第一個參數指向前一步返回的版本信息資源數據，第二個參數指向一個字符串：“\”，第三和第四個參數指向dw類型的變量lpBuffer和dwLen，返回到lpBuffer中的是指向一個VS_FIXEDFILEINFO結構的指針，這個結構中有定義的固定屬性的內容。
如果要獲取字符串類型信息塊中的版本信息，那就比較復雜一點了，必須首先知道語言集的名稱，所以先要獲取版本信息資源中變量類型信息塊的內容，方法是：
invoke VerQueryValue, addr dbVerInfo, addr szVarInfo, add lpBuffer, addr dwLen
mov eax, lpBuffer
mov eax, [eax]
ror eax, 16
szVarInfo是一個字符串：“\VarFileInfo\Translation”，這時函數在lpBuffer中返回語言集變量指針的指針，所以要先mov eax, lpBuffer，再用eax作指針用mov eax,[eax]得到語言集變量。語言集變量的高16位是字符集ID，低16位是語言ID，可以使用ror eax, 16來調換高低位，以我們的例子為例，現在eax中的值就是080404b0h了！
接下來就可以獲取字符串版本信息了，先將語言集的值通過vsprintf函數轉換成“080404b0”的形式，然后拼裝成“\StringFileInfo\080404b0\字符串名稱”形式的字符串，中間的“字符串名稱”可以是上表中的12種名稱之一，最后調用下面的語句（假定拼裝好的字符串地址為szString）。
invoke VerQueryValue, addr dbVerInfo, addr szString, addr lpBuffer, addr dwLen
執行后lpBuffer中會得到一個指針，指向版本信息字符串定義的內容，這就是我們最后需要的東西！重復這個步驟可以得到所有12種字符串版本信息。
Demo：獲得版本信息
//ShowVersionInfo.rc
//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
#include <resource.h>
//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
#define ICO_MAIN 0x1000 //圖標
#define DLG_MAIN 1
#define IDC_INFO 101
#define IDC_FILE 102
//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
ICO_MAIN ICON "Main.ico"
//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DLG_MAIN DIALOG 138, 123, 231, 139
STYLE DS_MODALFRAME | WS_POPUP | WS_VISIBLE | WS_CAPTION | WS_SYSMENU
CAPTION "查看PE文件版本信息"
FONT 9, "宋體"
{
EDITTEXT IDC_INFO, 5, 5, 220, 110, ES_MULTILINE | ES_AUTOVSCROLL | ES_AUTOHSCROLL | ES_READONLY | WS_BORDER | WS_VSCROLL | WS_TABSTOP
LTEXT "", IDC_FILE, 5, 123, 165, 8
DEFPUSHBUTTON "選擇文件(&B)", IDOK, 175, 120, 50, 14
}
//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
// ShowVersionInfo.asm
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; ShowVersionInfo.asm
; 顯示PE文件資源中版本信息的例子
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.386
.model flat, stdcall
option casemap :none
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Include 文件定義
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include windows.inc
include user32.inc
includelib user32.lib
include kernel32.inc
includelib kernel32.lib
include Version.inc
includelib Version.lib
include comctl32.inc
includelib comctl32.lib
include comdlg32.inc
includelib comdlg32.lib
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Equ 等值定義
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
ICO_MAIN equ 1000h
DLG_MAIN equ 1
IDC_INFO equ 101
IDC_FILE equ 102
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 數據段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.data?
hInstance dd ?
szBuffer db 4096 dup(?)
.const
szPeFileExt db 'PE文件',0,'*.exe;*.dll;*.scr;*.drv',0,0
szError db '文件中沒有包含版本信息!',0
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 代碼段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.code
include GetVersionInfo.inc
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_ProcDlgMain proc uses ebx edi esi hWnd, wMsg, wParam, lParam
local @szBuffer[MAX_PATH]:byte
local @stOpenFileName:OPENFILENAME
mov eax,wMsg
.if eax == WM_CLOSE
invoke EndDialog, hWnd, NULL
.elseif eax == WM_INITDIALOG
;*******************************************************************
; 設置標題欄圖標
;*******************************************************************
invoke LoadIcon, hInstance, ICO_MAIN
invoke SendMessage, hWnd, WM_SETICON, ICON_BIG, eax
.elseif eax == WM_COMMAND
mov eax, wParam
.if ax == IDOK
;*******************************************************************
; 打開一個選擇文件的對話框
;*******************************************************************
invoke RtlZeroMemory, addr @stOpenFileName, sizeof OPENFILENAME
invoke RtlZeroMemory, addr @szBuffer, sizeof @szBuffer
mov @stOpenFileName.lStructSize, SIZEOF @stOpenFileName
mov @stOpenFileName.Flags, OFN_FILEMUSTEXIST or OFN_PATHMUSTEXIST
push hWnd
pop @stOpenFileName.hwndOwner
mov @stOpenFileName.lpstrFilter, offset szPeFileExt
lea eax, @szBuffer
mov @stOpenFileName.lpstrFile, eax
mov @stOpenFileName.nMaxFile, MAX_PATH
invoke GetOpenFileName, addr @stOpenFileName
.if eax
;*******************************************************************
; 獲取版本信息并顯示出來
;*******************************************************************
invoke _GetVersionInfo, addr @szBuffer, addr szBuffer
.if eax
invoke SetDlgItemText, hWnd, IDC_FILE, addr @szBuffer
invoke SetDlgItemText, hWnd, IDC_INFO, addr szBuffer
.else
invoke MessageBox, hWnd, addr szError, NULL, MB_OK or MB_ICONHAND
.endif
.endif
.endif
;*******************************************************************
.else
mov eax, FALSE
ret
.endif
mov eax, TRUE
ret
_ProcDlgMain endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
start:
invoke InitCommonControls
invoke GetModuleHandle, NULL
mov hInstance, eax
invoke DialogBoxParam, hInstance, DLG_MAIN, NULL, offset _ProcDlgMain, NULL
invoke ExitProcess, NULL
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
end start
// GetVersionInfo.inc
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Sample code for < Win32ASM Programming >
; by 羅云彬, http://asm.yeah.net
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; GetVersionInfo.inc
; 用來獲取 PE 文件資源中版本信息的子程序
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 通過 include 語句包含到其它源程序中使用
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.const
szRoot db '\',0
szVarInfo db '\VarFileInfo\Translation',0
szStrInfoFmt db '\StringFileInfo\%08x\',0
szArrow db ' --> ',0
szReturn db 0dh,0ah,0
szFixFileInfo db '固定版本信息屬性：',0dh,0ah
db 'FileVersion: %d.%d.%d.%d',0dh,0ah
db 'ProductVersion: %d.%d.%d.%d',0dh,0ah
db 'FileOS: %08x',0dh,0ah
db 'FileType: %08x',0dh,0ah,0dh,0ah
db '字符串版本屬性：',0dh,0ah,0
;********************************************************************
szStr1 db 'Comments',0
szStr2 db 'CompanyName',0
szStr3 db 'FileDescription',0
szStr4 db 'FileVersion',0
szStr5 db 'InternalName',0
szStr6 db 'LegalCopyright',0
szStr7 db 'LegalTrademarks',0
szStr8 db 'OriginalFilename',0
szStr9 db 'PrivateBuild',0
szStr10 db 'ProductName',0
szStr11 db 'ProductVersion',0
szStr12 db 'SpecialBuild',0
;********************************************************************
lpStr1 dd szStr1
lpStr2 dd szStr2
lpStr3 dd szStr3
lpStr4 dd szStr4
lpStr5 dd szStr5
lpStr6 dd szStr6
lpStr7 dd szStr7
lpStr8 dd szStr8
lpStr9 dd szStr9
lpStr10 dd szStr10
lpStr11 dd szStr11
lpStr12 dd szStr12
.code
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 獲取文件版本信息
; 入口參數：文件名，返回信息緩沖區
; 返回參數：TRUE = 成功，FALSE = 失敗
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_GetVersionInfo proc _lpFileName,_lpBuffer
local @dbVerInfo[4096]:byte
local @szStringInfo[128]:byte
local @szString[128]:byte
local @lpBuffer,@dwLen
local @dwVer1,@dwVer2,@dwVer3,@dwVer4
local @dwVer5,@dwVer6,@dwVer7,@dwVer8
pushad
invoke GetFileVersionInfoSize,_lpFileName,NULL
.if !eax
popad
xor eax,eax
ret
.endif
invoke GetFileVersionInfo,_lpFileName,NULL,sizeof @dbVerInfo,addr @dbVerInfo
;********************************************************************
; 獲取固定屬性
;********************************************************************
invoke VerQueryValue,addr @dbVerInfo,addr szRoot,addr @lpBuffer,addr @dwLen
mov esi,@lpBuffer
assume esi:ptr VS_FIXEDFILEINFO
;********************************************************************
; 計算版本號
;********************************************************************
mov eax,[esi].dwFileVersionMS
movzx ecx,ax
mov @dwVer2,ecx
shr eax,16
mov @dwVer1,eax
mov eax,[esi].dwFileVersionLS
movzx ecx,ax
mov @dwVer4,ecx
shr eax,16
mov @dwVer3,eax
mov eax,[esi].dwProductVersionMS
movzx ecx,ax
mov @dwVer6,ecx
shr eax,16
mov @dwVer5,eax
mov eax,[esi].dwProductVersionLS
movzx ecx,ax
mov @dwVer8,ecx
shr eax,16
mov @dwVer7,eax
invoke wsprintf,_lpBuffer,addr szFixFileInfo,\
@dwVer1,@dwVer2,@dwVer3,@dwVer4,\
@dwVer5,@dwVer6,@dwVer7,@dwVer8,\
[esi].dwFileOS,[esi].dwFileType
assume esi:nothing
;********************************************************************
; 獲取語言集
;********************************************************************
invoke VerQueryValue,addr @dbVerInfo,addr szVarInfo,addr @lpBuffer,addr @dwLen
mov eax,@lpBuffer
mov eax,[eax]
ror eax,16
invoke wsprintf,addr @szStringInfo,addr szStrInfoFmt,eax
;********************************************************************
; 獲取字符串版本信息
;********************************************************************
mov ebx,offset lpStr1
.while ebx <= offset lpStr12
invoke lstrcpy,addr @szString,addr @szStringInfo
mov eax,[ebx]
invoke lstrcat,addr @szString,eax
mov eax,[ebx]
invoke lstrcat,_lpBuffer,eax
invoke lstrcat,_lpBuffer,addr szArrow ;加上 -->
invoke VerQueryValue,addr @dbVerInfo,addr @szString,addr @lpBuffer,addr @dwLen
.if eax
invoke lstrcat,_lpBuffer,@lpBuffer ;加上獲得的版本信息
.endif
invoke lstrcat,_lpBuffer,addr szReturn ;加上回車
add ebx,4
.endw
popad
mov eax,TRUE
ret
_GetVersionInfo endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>