如果您見過本人的文章"Window簡介(二) 如何攔截ComboBox MouseMove"應可以了解SubClass的動作是針對某一個Window來動作，像上面的這個文章就告訴大家如何透過SubClass來讓 ComboBox能偵測到MouseMove，而如果有一群ComboBox全要偵測到MouseMove那不就每一個ComboBox都要來做 SubClass的動作，有沒有一次完成不要如此麻煩的呢？原則上這是使用SuperClass可完成，SuperClass的作法是：

  1.取得原本Class的設定(如:原本ComboBox的設定)，可用GetClassLong來取得
  2.更動Class的設定，可用SetClassLong來設定
  3.依新的設定Create控制項，而且唯有新Create出的控制項才有作用，舊有的沒有受
    影響。

再來看一下GetClassLong,SetClassLong的第一個叁數，它是hWnd，想想看，這是更動某一個Class的API，而不是只更動 某個Window的API，怎麼傳入hWnd，沒錯，那是間接的作法，由hWnd可以得知那是屬於哪一種Class的控制項，進而改變/取得 該hWnd所屬Class類別的設定。那現在就出現一個問題，我們要先Create出一個Window(控制項)而後才能取得其hWnd，之後才下 SetClassLong來更動設定，而這個Window因為是在更動設定之前所造出來的，所以新的設定沒有在這個Window上作用(這是Window 的作法，沒有辦法)，所以我們說不得，只好將該Window Kill掉，之後Create的Window才是我們想要的。如果使用的是純Window API的設計，可能不用如此，而使用以下三個步驟：

   1.取得Class的設定，使用GetClassInfoEx()取得，并記錄下來
   2.更動原先的記錄，將之變成另外一個Class
   3.注冊該Class,并CreateWindow

但這樣做，就沒有vb的使用者介面，將Control項放到Form上那麼容易，一切都用API來做，我想沒有人會如此吧？

所以啦，在VB的話，就只好使用物件陣列的作法，因為透過它，可以做到到動態新增、移除Control項的功能，不過正因它是事後才產生的，所以我們對之的控制相對的就要付出代價(如：位置的設定)。

注釋：以下程式在module1.bas
Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" _
  (ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal Msg As Long, _
   ByVal wParam As Long, ByVal lParam As Long) As Long
Declare Function SetClassLong Lib "user32" Alias "SetClassLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Declare Function GetClassLong Lib "user32" Alias "GetClassLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long

Public Const GCL_WNDPROC = (-24)
Public Const WM_MOUSEMOVE = &H200

Public preWinProc As Long

Public Function wndproc(ByVal hwnd As Long, ByVal Msg As Long, _
                         ByVal wParam As Long, ByVal lParam As Long) As Long
注釋：以下程式會截取mouse move，處理完後，再將之送往原來的Window Procedure

If Msg = WM_MOUSEMOVE Then
    注釋：請處理Mouse Move的動作
    Debug.Print "Combol Mouse Move , hwnd="; hwnd
End If
注釋：將之送往原來的Window Procedure
wndproc = CallWindowProc(preWinProc, hwnd, Msg, wParam, lParam)
End Function

注釋：以下程式在Form1, form1中有一Combo1并事先設定其Index =1
Sub Form_Load()
Dim ret As Long
Combo1(1).Move 5, 5
注釋：記錄原本的Window Procedure的位址
preWinProc = GetClassLong(Combo1(1).hwnd, GCL_WNDPROC)
注釋：設定Combo1的window Procedure到wndproc
ret = SetClassLong(Combo1(1).hwnd, GCL_WNDPROC, AddressOf wndproc)
注釋：動態產生兩個Combo，Mouse在這兩個Combo上才會偵測到MouseMove
Load Combo1(2)
Combo1(2).Move 5, 400
Combo1(2).Visible = True
Load Combo1(3)
Combo1(3).Move 5, 800
Combo1(3).Visible = True
Debug.Print "Combo1(1).Hwnd="; Combo1(1).hwnd
Debug.Print "Combo1(2).Hwnd="; Combo1(2).hwnd
Debug.Print "Combo1(3).Hwnd="; Combo1(3).hwnd
End Sub

Private Sub Form_Unload(Cancel As Integer)
Dim ret As Long
注釋：取消Message的截取，而使之又只送往原來的Window Procedure
ret = SetClassLong(Combo1(1).hwnd, GCL_WNDPROC, preWinProc)
End Sub