補：沒辦法；俺的cnit的博客發(fā)布不上去，就發(fā)在俺的cpp博客吧。
由于工作緣故，需要處理一接口發(fā)送來的xml串，對方采用java以字節(jié)流模式post一個xml串，
在asp中采用request估計把它加載到xml解析器中應(yīng)該報無法解析。
采用Request.binaryRead 即可解決，但是要注意幾個細節(jié)方面。
一一到來。
1. 讀取字節(jié)流
Dim vtBody
iReceive = Request.TotalBytes
vtBody = Request.BinaryRead(iReceive)
2. 轉(zhuǎn)換字節(jié)流為字符串，有以下幾個函數(shù)可以任選。
' a。byte --> str ,該轉(zhuǎn)換只適用小數(shù)據(jù)，但是所有ie沒有問題，，，
Function bytes2BSTR(vIn)
strReturn = ""
For i = 1 To LenB(vIn)
ThisCharCode = AscB(MidB(vIn,i,1))
If ThisCharCode < &H80 Then
strReturn = strReturn & Chr(ThisCharCode)
Else
NextCharCode = AscB(MidB(vIn,i+1,1))
strReturn = strReturn & Chr(CLng(ThisCharCode) * &H100 + CInt(NextCharCode))
i = i + 1
End If
Next
bytes2BSTR = strReturn
End Function
'b。采用 ado record來轉(zhuǎn)換，該轉(zhuǎn)換速度快，轉(zhuǎn)換數(shù)據(jù)大，據(jù)說對ie5支持不夠好，
function rsbinarytostring(xbinary)
Dim binary
If vartype(xbinary)= 8 then
binary = multibytetobinary(xbinary)
Else
binary = xbinary
End If
Dim rs, lbinary
const adlongvarchar = 201
Set rs = createobject("adodb.recordset")
lbinary = lenb(binary)
If lbinary>0 Then
rs.fields.append "mbinary", adlongvarchar, lbinary
rs.open
rs.addnew
rs("mbinary").appendchunk binary
rs.update
rsbinarytostring = rs("mbinary").Value
rs.Close
Else
rsbinarytostring = ""
end if
End Function
'***************************************************
'c。采用流解析字符串，該轉(zhuǎn)換速度快，轉(zhuǎn)換數(shù)據(jù)大，據(jù)說對ie5支持不夠好，
function stream_binarytostring(binary, charset)
set binarystream = createobject("adodb.stream")
'讀入字節(jié)流
binarystream.type = 1
binarystream.open
binarystream.write binary
'內(nèi)部以字符方式返回
binarystream.position = 0
binarystream.type = 2
If len(charset) > 0 Then
binarystream.charset = charset
Else
binarystream.charset = "us-ascii"
End If
stream_binarytostring = binarystream.readtext
end function
則調(diào)用上面任一個進行轉(zhuǎn)換即可。如：
strBody = stream_binarytostring(vtBody, "utf-8")
3. 將strBody解碼
如果調(diào)用Response.Write strBody ，則在ie上可以看到正常的xml結(jié)構(gòu)體部分。
但是如果你要是寫在文本中，你將會看到的是如下的樣式：
%3C%3Fxml+version+%3D+%221.0%22+encoding%3D%22UTF-8%22+%3F%3E%3CROOT%3E%3CUSER%3Egtzx%3C%2FUSER%3E%3CPASS%3Egtzx%3C%2FPASS%3E%3CMO%3E%3CMOID%3E291AC5FDBD0DF4EF2B2A2950FB730610%3C%2FMOID%3E%3CMSGFORMAT%3E15%3C%2FMSGFORMAT%3E%3CCLASSID%3Ehttp%3A%。。。。%3E%3CSERVICEID%3E1981%3C%2FSERVICEID%3E%3CCITYID%3E102%3C%2FCITYID%3E%3CPROVINCEID%3E16%3C%2FPROVINCEID%3E%3CMOUSEID%3E2%3C%2FMOUSEID%3E%3CSPNUMBER%3E10666066%3C%2FSPNUMBER%3E%3CLINKID%3E%3C%2FLINKID%3E%3CREMARK%3E%3C%2FREMARK%3E%3C%2FMO%3E%3C%2FROOT%3E
這表示是url 編碼方式，它把utf-8編碼進行了再一次編碼，如果你要是xml解析器來解析的話，恐怕它是干不了活的。（也許有，但是asp中玩那個xmldocument實在是不想研究下去）
不過再需要做個urlDecode轉(zhuǎn)換，這個asp函數(shù)，網(wǎng)上一大把，搜出一個，粘貼下來就可以去掉%并轉(zhuǎn)換utf-8格式。這里貼出一個修改的urlDecode函數(shù)，
'*****************************************************
'功能描述：URL解碼碼函數(shù)
'輸入?yún)?shù)：vURL編碼的字符串
'返回值：解碼后的字符串
Public Function URLDecoding(sIn)
Dim s,i,l,c,t,n : s="" : l=Len(sIn)
For i=1 To l
c=Mid(sIn,i,1)
If c<>"%" Then
s = s & c
Else
c=Mid(sIn,i+1,2) : i=i+2 : t=CInt("&H" & c)
If t<&H80 Then
s=s & Chr(t)
Else
c=Mid(sIn,i+1,3)
If Left(c,1)<>"%" Then
URLDecoding=s
Exit Function
Else
c=Right(c,2) : n=CInt("&H" & c)
t=t*256+n-65536
s = s & Chr(t) : i=i+3
End If
End If
End If
Next
s=Replace(s, "+"," ")
URLDecoding=s
End Function
4. 調(diào)用xml解析器，加載以上字符串，即可解決。
'***********************************************************
'解析xml文件
'***********************************************************
Dim xml
Set xml = Server.CreateObject ("msxml2.DOMDocument")
xml.Async = False
xml.Loadxml(strBody)
5.讀出xml中的節(jié)點，寫入文本或者寫入數(shù)據(jù)庫，ok。
總結(jié)：
在asp中采用xmlhttp發(fā)送或者接收，是不考慮字節(jié)流模式發(fā)送的，直接調(diào)用xmlhttp中的send即可。管它是
按啥模式發(fā)送的，但是在其他語言編程中，比如java，c#，or vc中，有可能是按字節(jié)流方式發(fā)送出去的，那么，
如果想圖個方便，直接用asp寫個接口處理下，就要考慮下和其他程序處理的細節(jié)。