第2課：保護模式

聲明：轉載請保留：

譯者：http://m.shnenglu.com/jinglexy

原作者：xiaoming.mo at skelix dot org

目標        下載源程序

如前文所述，系統上電時處理器處于實模式。事實上，它還有另外一種工作模式：保護模式。skelix從磁盤啟動后即進入該模式。在本課中我們進入保護模式并打印"Hello World!"。

保護模式的優點

在實模式下，處理器不能簡單尋址1MB以外的物理地址（實際上用某些方法是可以的），這等內存實在是太少了。所以i386系列處理器提供了保護模式：基于特權級的保護和訪問更大的內存地址范圍。我們在這里講的是32位保護模式，16位保護模式不在討論之列。

保護模式最大的好處就是可以直接范圍最大4GB的地址空間，但是經過多年的更新換代，我們的機器還沒有達到4GB內存，于是引入了虛擬內存的概念，它可以使用硬盤存儲空間作為內存使用。保護模式下對內存訪問進行保護，它阻止用戶程序對內核代碼或數據的訪問，應用程序的crash也不會影響到整個系統。單個進程可以訪問自己獨有的4GB虛擬地址空間，而不是混亂在整個內存里面使用，它是通過地址映射來實現的，即邏輯地址轉換成虛擬地址的過程。更詳細的內容可以參考Intel的文檔。

概述運行原理

好了，讓我們結束無聊的理論知識吧，本課的目的是使我們的程序進入到保護模式。在保護模式中，我們仍然使用段（事實上，我們無法在處理器上禁用段特性），每個段可以訪問單獨的4GB地址空間。段轉載在寄存器中，它表示一個描述符選擇子，和實模式一樣使用cs，ds等16位寄存器。這樣說吧：一個內存段描述符寄存器 CS = 0x8，我們可以直接訪問0到4G-1地址空間，注意我說的是“可以”，因為可以根據需要設置這個段有多大，而不是象實模式那樣限制在64KB。

我上面提到段是用選擇子來表示的，這個說法可能不是很準確，實際上選擇子是段描述符表的索引。這個描述符表是系統所有可以使用的段的地址和范圍表的入口，一個描述符包括段起始地址，長度，類型（數據/代碼/門），特權級等。為了范圍到特定的內存地址，段選擇子和偏移地址表示為如下形式：selector:offset，和實模式一樣。例如，我們讓 0x08選擇子指向B8000（視頻內存區域） 開始的內存范圍，這樣我們可以使用8:00000000來范圍視頻內存區域的第一個字節。在系統中存在以下幾種描述符表：GDT（全局描述符表），LDT（局部描述符表），IDT（中斷描述符表）。當進入到保護模式后，所有的內存范圍都通過GDT或LDT。

在本課中我們使用GDT，正如它的名字“全局”，GDT可以被所有任務共享?，F在我們來使用一個代碼段和一個數據段。

下面是代碼段/數據段描述符的格式，一個描述符是8字節長（64位）：

 63_______________56__55__54__53__52__51_____________48_

| 基地址（31到24位） | G |D/B| X | U | 長度（19到16位） |

|_______________________________________________________|

 _47__46__45__44____41______40____39_________________32_

| P |  DPL |     類型    |  A   |  基地址（23到16位）   |

|_______________________________________________________|

 31____________________________________________________16

|                    基地址（15到0位）                  |

|_______________________________________________________|

 16_____________________________________________________

|                    長度（15到0位）                    |

|_______________________________________________________|

解釋一下：為什么長度只有20位呢，這是因為粒度一般設置位4K，所以可以表示0到4GB大小的長度范圍。

                                   表-域說明

我們從上面看到，一個描述符保護32位基地址和20位段長界限等屬性。32位基地址表示32位物理地址，是一個段的開始地址，20位長度界限表示這個段的長度。讀者可能注意到2^20只能表示1M大小范圍。為了訪問4GB地址范圍，描述符中使用了G位來表示粒度。當G位為1時，粒度為4K，這是可以訪問的范圍是1M * 4K，即4GB大??；如果G為為0，粒度為1字節，可以訪問的范圍是1M字節大小。

特權級保護是保護模式的重要概念，為了解釋這個，我們來看一下描述符選擇子。上面已經提到了，選擇子是描述符表的一個索引：

 15______________________________3___2____1___0__

|              Index              | TI |   RPL  |

|_______________________________________________|

應用程序特權級（PL）和 cs寄存器中的PL（即RPL）是類似的。程序在低的特權級（即PL值更高）不能訪問高特權級的數據段或執行高特權級的代碼段。當選擇子載入到寄存器中時，處理器會檢查CPL和RPL，根據這兩個PL得到一個EPL（恕我直言，作者增加了一個新的概念并不明智），然后比較EPL和描述符中的DPL。當EPL的特權級更高時，才能正確訪問目標段。注意，這里只是大致遵循該法則，處理器還要檢測讀寫屬性，存在位等。正如上面圖所描述，選擇子Index是13位的，所以最多可以索引2^13個描述符，即8096個。這只是在GDT中最多索引的描述符個數，另外每個進程都可以有自己的LDT。處理器會保留第一個GDT中的描述符，它應當被清0，不應當用作訪問內存使用。

進入保護模式

在上一課中，我們從軟盤啟動skelix?，F在我們可以執行到實模式代碼，并進入保護模式了，一些模式切換的代碼必不可少，并且不準備讓skelix在返回到那黑暗時代－實模式了。在進入保護模式之前，需要做一些準備工作，我們先創建GDT：

02/bootsect.s

gdt:
        .quad    0x0000000000000000 # 空描述符
        .quad    0x00cf9a000000ffff # cs
        .quad    0x00cf92000000ffff # ds
        .quad    0x0000000000000000 # 用作將來的段描述符
        .quad    0x0000000000000000 # 用作將來的段描述符

可以看到，我們在上面定義了5個GDT描述符，但暫時只用到了第2個和第3個。第一個dummy描述符是Intel規定的，第2個是cs段（代碼段）描述符，下面我們仔細分析一下這個8字節值：（紅色表示cs描述符的值域）

根據上面的解釋，這個段描述符描述的段從00000000地址開始，界限是FFFFF*4K，即4G的32位代碼段。第3個描述符用于數據段或堆棧段，區別在于第43位，設置為0表示數據段。

好了，還是讓程序的使用來說明一切吧。處理器有幾個專門的寄存器用于保護模式，GDTR寄存器使用LGDT來加載，GDTR是48位寄存器，低16位表示GDT的長度，高32位表示GDT的基地址。

02/bootsect.s

gdt_48:
        .word  .-gdt-1        當前地址減gdt地址減1得到GDT的長度
        .long  GDT_ADDR       這里使用了一些常量，如GDT_ADDR，定義在一個頭文件中

02/include/kernel.inc

.set CODE_SEL, 0x08        # 內核代碼段選擇子，二進制值是00001000，表示GDT的第2項（索引值為1）
.set DATA_SEL, 0x10        # 內核代碼段選擇子
.set IDT_ADDR, 0x80000     # IDT 起始地址

我們將所有數據設置為固定地址，IDT表（后面課程會介紹到）是所有數據的起始部分。

.set IDT_SIZE, (256*8)     # IDT 大小
.set GDT_ADDR, (IDT_ADDR+IDT_SIZE)        # GDT 在 IDT的后面

我們用GDT_ADDR，而不是用bootsector.s文件中的gdt符合，是因為在進入保護模式后7c00地址將被覆蓋，于是我們把系統中用到的一些表搬移到固定地址。

.set GDT_ENTRIES, 5        # GDT 有 5個描述符
                           # 空描述符
                           # 內核代碼段描述符
                           # 內核數據段描述符
                           # 當前進程tss
                           # 當前進程ldt

在skelix我們使用了5個GDT描述符，這里我們先介紹前3個，最后兩個將會在后面的課程中介紹。
.set GDT_SIZE, (8*GDT_ENTRIES)
                           # GDT 大小，每個描述符是8個字節大小，所以GDT大小是該值，但是我們用的并不是它
.set KERNEL_SECT, 72       # 內核大小，單位是，36k對于現在來說已經足夠了
.set STACK_BOT, 0xa0000    # 堆棧從640K 內存處開始向下增長，應該是STACK_TOP才對？

下載我們來看一下引導程序
02/bootsect.s

        .text
        .globl    start
        .include "kernel.inc"
include the above file
        .code16
start:
        jmp        code
gdt:  
        .quad    0x0000000000000000 # null descriptor
        .quad    0x00cf9a000000ffff # cs
        .quad    0x00cf92000000ffff # ds
        .quad    0x0000000000000000 # reserved for further use
        .quad    0x0000000000000000 # reserved for further use
gdt_48:
        .word    .-gdt-1
        .long    GDT_ADDR
code:
        xorw    %ax,    %ax
        movw    %ax,    %ds    # 數據段 = 0x0000
        movw    %ax,    %ss    # 堆棧段 = 0x0000
        movw    $0x1000,%sp    # 保護模式前用的堆棧，不要讓他覆蓋到7c00處的引導程序即可

        # 我們將加載內核到地址 0x10000
        movw    $0x1000,%ax
        movw    %ax,    %es
        xorw    %bx,    %bx    # es:bx 加載內核的目標地址
        movw    $KERNEL_SECT,%cx
        movw    $1,     %si    # 0，跳過去，所以是1
rd_kern:
        call    read_sect      # 入口參數：si是起始扇區數，es:bx是指定內存地址
        addw    $512,    %bx
        incw    %si
        loop    rd_kern

我們先把內核讀到0x10000這個臨時地址，然后再把它搬移到0x0（進入保護模式后搬移）。這個函數講起來有些煩，讀者可以自己分析：）

        cli                    # 就要進入保護模式了，所以關掉實模式下的中斷

        cld                    # 將內核的前512字節移到0x0
        movw    $0x1000,%ax
        movw    %ax,    %ds
        movw    $0x0000,%ax
        movw    %ax,    %es
        xorw    %si,    %si
        xorw    %di,    %di
        movw    $512>>2,%cx
        rep
        movsl

為什么要這樣做？因為內核的這個部分是load.s這個文件編譯出來的（本課后面會介紹到），load.s會讀取“真正的內核”到0x200處，但是在這一課，我們只準備打印"Hello World!"，除此之外什么都不做。

        xorw    %ax,    %ax
        movw    %ax,    %ds    # 復位 ds 為 0x0000

        movw    $GDT_ADDR>>4,%ax       # (0x80000 + 256 * 8) >> 2
        movw    %ax,    %es            # gdt所在的數據段
        movw    $gdt,   %si
        xorw    %di,    %di            # 從ds:si 拷貝到 es:di中
        movw    $GDT_SIZE>>2,%cx       # 拷貝數據段中的gdt到指定地址
        rep
        movsl

enable_a20:        
        inb    $0x64,   %al   
        testb  $0x2,    %al
        jnz    enable_a20
        movb   $0xbf,   %al
        outb   %al,     $0x64

這種開啟a20地址線的方法來自一本書："The Undocumented PC"，中文紙版是《PC技術內幕》，可惜已絕版。a20地址線通過鍵盤控制器一個端口使能（ibm早期這樣設計），當系統啟動時，該地址線是關閉的，使能它之后才能訪問1MB以外的地址空間。

        lgdt    gdt_48                 # 加載gdt地址到寄存器中
        # 進入保護模式
        movl   %cr0,    %eax
        orl    $0x1,    %eax
        movl   %eax,    %cr0           # 使能CR0 控制寄存器中的PE位（即第0位）

現在我們已經進入到保護模式了，是不是簡單的另你不敢相信？呵呵

        ljmp   $CODE_SEL, $0x0

我們還需要進行一個絕對地址跳轉，因為解碼管線中預取了16位指令，需要刷新成后面的32位指令。關于ia32的指令預取和解碼管線，網絡上有很多相關的文章，建議讀者閱讀一下相關文章。這個指令跳轉到0x08描述符選擇子指向的偏移0x的指令處，并開始執行，這個描述符即GDT中的第2項：內核代碼段描述符。代碼就是load.s的開始處，一會我們開始分析load.s這個程序。

bootsector.s中的函數：

        # 輸入:    si:    LBA 地址，從0開始
        # 輸出     es:bx  讀取扇區到這個內存地址
read_sect:
        pushw   %ax
        pushw   %cx
        pushw   %dx
        pushw   %bx

        movw    %si,    %ax       
        xorw    %dx,    %dx
        movw    $18,    %bx    # 對于1.44M軟盤：每磁道18扇區

        divw    %bx
        incw    %dx
        movb    %dl,    %cl    # cl = 扇區號
        xorw    %dx,    %dx
        movw    $2,     %bx    # 每磁道2磁頭
        divw    %bx

        movb    %dl,    %dh    # 磁頭
        xorb    %dl,    %dl    # 軟驅號
        movb    %al,    %ch    # 柱面

        popw    %bx            # 讀取到：es:bx
rp_read:
        movb    $0x1,   %al    # 讀1個扇區
        movb    $0x2,   %ah
        int     $0x13
        jc      rp_read
        popw    %dx
        popw    %cx
        popw    %ax
        ret

.org    0x1fe,  0x90              # 填充nop指令，機器碼是0x90
.word   0xaa55

當我們進入到保護模式后，所有的通用寄存器和段寄存器保持原來實模式的值，代碼段從特權級0開始執行。load.s文件將從地址0處開始執行。
02/load.s

        .text
        .globl    pm_mode
        .include "kernel.inc"
        .org 0                    # 告訴加載器，該代碼將從邏輯地址0開始執行。它也是物理地址0。

pm_mode:
        movl    $DATA_SEL,%eax
        movw    %ax,    %ds
        movw    %ax,    %es
        movw    %ax,    %fs
        movw    %ax,    %gs
        movw    %ax,    %ss
        movl    $STACK_BOT,%esp   # 所有數據段選擇子設置為0x10，即GDT的第3項，特權級為0。這個步驟非常重要！

        cld
        movl    $0x10200,%esi     # 在bootsector程序中，我們將內核加載到了0x10200這個地址
        movl    $0x200, %edi      # 現在把內核搬移到0x200
        movl    $KERNEL_SECT<<7,%ecx        # 拷貝2^7次方個，注意下面是movsl，每次4個字節
        rep
        movsl

        movb    $0x07, %al                  # 顏色
        movl    $msg,  %esi
        movl    $0xb8000,%edi
1:
        cmp     $0,    (%esi)               # 打印"Hello World!"字符串
        je      1f
        movsb
        stosb
        jmp     1b
1:      jmp     1b
msg:
                .string "Hello World!\x0"

現在我們用圖來清晰的描述它，引導程序被加載在00007c00，它設置棧頂在00001000，然后讀取內核到00001000，然后把內核映象的前一個sector（即load.s）程序讀到地址0。在load.s程序中移到內核到地址0。

        圖1                                        圖2

|                   |                    |___________________|a0000

|                   |                    |       內核棧      |

|       GDT         |                    |                   |

|       IDT         |                    |       GDT/IDT     |

|___________________| 8000：系統數據     |___________________|80000

|                   |                    |                   |

|                   |                    |                   |

|                   |                    |                   |

|       內核        |                    |                   |

|                   |                    |                   |

|___________________|10000               |                   |

|                   |                    |                   |

|                   |                    |                   |

|___________________|7e00                |                   |

|     bootsector.s  |                    |                   |

|___________________|7c00                |                   |

|                   |                    |                   |

|                   |                    |___________________|

|                   |                    |                   |

|                   |                    |                   |

|___________________|1000                |       內核        |

|      stack        |                    |                   |

|___________________|200                 |___________________|200

|      load.s       |                    |                   |

|___________________|0                   |___________________|0

當進入到保護模式后，load.s移到內核到它后面，設置內核棧，如圖2。

最后，我們翻開Makefile看看：
02/Makefile

AS=as -Iinclude            -I選項告訴匯編工具查找頭文件的路徑
LD=ld

KERNEL_OBJS= load.o        到現在為止，內核只保護load.s匯編文件
.s.o:
    ${AS} -a $< -o $*.o >$*.map

all: final.img

final.img: bootsect kernel
    cat bootsect kernel > final.img
    @wc -c final.img

bootsect: bootsect.o
    ${LD} --oformat binary -N -e start -Ttext 0x7c00 -o bootsect $<

kernel: ${KERNEL_OBJS}
    ${LD} --oformat binary -N -e pm_mode -Ttext 0x0000 -o $@ ${KERNEL_OBJS}
    @wc -c kernel

內核代碼段鏈接在0x0000
clean:
    rm -f *.img kernel bootsect *.o

執行make，用vmware運行一下剛才的image看看，是不是hello world呢。