1、在安裝腳本的開始處定義 LIBRARY_X64。

!include "MUI.nsh"
!include "Library.nsh"

;如果做32位安裝包就把下句注釋。
!define LIBRARY_X64

2、注冊(cè)COM組件，需包含Library.nsh，用宏InstallLib/UnInstallLib 代替RegDLL/UnRegDLL。

;RegDLL "$SYSDIR\ComName.dll"
!insertmacro InstallLib REGDLL NOTSHARED REBOOT_NOTPROTECTED "LocalPath\ComName.dll" "$SYSDIR\ComName.dll" $SYSDIR

;UnRegDLL "$SYSDIR\ComName.dll"
!insertmacro UnInstallLib REGDLL NOTSHARED REBOOT_NOTPROTECTED "$SYSDIR\ComName.dll"

3、在調(diào)用涉及注冊(cè)表的函數(shù)前用 SetRegView 64，后用 SetRegView lastused。

!ifdef  LIBRARY_X64
 SetRegView 64
!endif

 WriteRegStr ...
 WriteRegStr ...
 WriteRegStr ...

!ifdef  LIBRARY_X64
 SetRegView lastused
!endif 

SetRegView用戶手冊(cè)：
在 Windows x64 上共有2種查看方式。一種用于 32-bit 應(yīng)用程序，另一種用于 x64 應(yīng)用程序。默認(rèn)情況下，32-bit 應(yīng)用程序運(yùn)行在 x64 系統(tǒng)的 WOW64 模式下時(shí)，只允許使用 32-bit 查看方式。使用 SetRegView 64 將允許安裝程序在 x64 中訪問注冊(cè)表鍵值。

它將影響
DeleteRegKey,
DeleteRegValue,
EnumRegKey,
EnumRegValue,
ReadRegDWORD,
ReadRegStr,
WriteRegBin,
WriteRegDWORD,
WriteRegStr,
WriteRegExpandStr。

它不會(huì)影響 InstallDirRegKey。另外，在函數(shù) .onInit 中也可使用 ReadRegStr 讀取注冊(cè)表。

SetRegView 32
ReadRegStr $0 HKLM Software\Microsoft\Windows\CurrentVersion ProgramFilesDir
DetailPrint $0 # prints C:\Program Files (x86)
SetRegView 64
ReadRegStr $0 HKLM Software\Microsoft\Windows\CurrentVersion ProgramFilesDir
DetailPrint $0 # prints C:\Program Files

Function .onInit
  SetRegView 64
  ReadRegStr $INSTDIR HKLM Software\NSIS ""
  SetRegView 32
FunctionEnd

4、在調(diào)用涉及目標(biāo)機(jī)器上系統(tǒng)目錄（即$SYSDIR）的函數(shù)前用 ${DisableX64FSRedirection}。

在安裝包的第一個(gè)Section中調(diào)用一次即可。
!ifdef  LIBRARY_X64
 ${DisableX64FSRedirection}
!endif 

5、在64位系統(tǒng)上 $PROGRAMFILES64 表示“Program Files”, $PROGRAMFILES 表示 “Program Files (x86)”。

可以在安裝腳本的開始處定義一個(gè)常量，
!ifdef LIBRARY_X64
!define PROGRAM_FILES_MAP  $PROGRAMFILES64
!else
!define PROGRAM_FILES_MAP  $PROGRAMFILES
!endif
以后直接用 ${PROGRAM_FILES_MAP} 代替 $PROGRAMFILES。

6、在.onInit 和 un.onInit 中判斷一下，如果安裝包是在32位操作系統(tǒng)上運(yùn)行，則停止安裝。

可創(chuàng)建一個(gè)宏，然后在需要的地方插入。
!macro TIP_WHEN_AMD64_INSTALLER_RUNAT_X86
 !ifdef LIBRARY_X64
  ${If} ${RunningX64}
  ${else}
     MessageBox MB_OK|MB_ICONINFORMATION "請(qǐng)?jiān)?4位操作系統(tǒng)下運(yùn)行。"
   Abort
  ${EndIf}
 !endif
!macroend

Function .onInit
 !insertmacro TIP_WHEN_AMD64_INSTALLER_RUNAT_X86
 SetShellVarContext all  ;安裝到所有用戶下，current 表示安裝到當(dāng)前用戶下, all 表示所有用戶下。
FunctionEnd

Function un.onInit
 !insertmacro TIP_WHEN_AMD64_INSTALLER_RUNAT_X86
 SetShellVarContext all
FunctionEnd

備注：
1、在 NSIS 中的條件編譯是 !開頭，不是 #開頭，如!ifdef。
2、對(duì)COM組件，我認(rèn)為應(yīng)該是使用 NOTSHARED 方式注冊(cè)。
3、可以做個(gè)批處理文件，一次性生成32位/64位的安裝包。
 如 x.bat
 rem "記得要把安裝腳本中的 !define LIBRARY_X64 注釋掉，否則不能生成32位安裝包。"
 makensis .\myinstaller.nsi
 makensis /DLIBRARY_X64 .\myinstaller.nsi
 pause